Check if a least one Colum/field is blank

[SkrOYC]

I need to make a condition for an action that takes the user to a certain view to complete info for certain rows if at least one of them is blank.
I’m stuck thinking about this.
SELECT() might help but I want to keep it simple.
This didn’t work:

COUNT([CMVINV_Inline][ID_INVITEMS])<>COUNT([CMVINV_Inline][PRECIO_U])

CMVINV_Inline has the list of values to check. List column type
[ID_INVITEMS] is the Key column.
[PRECIO_U] is the column that can’t be blank

The condition is for an action that shouldn’t be enabled if there is no blank field inside [CMINV_Inline][PRECIO_U]

This should be very simple but I’m smashing my head against the wall with this.
I count on you guys

[SkrOYC]

Update

Tried with

IN(
  "",
  [CMVINV_Inline][PRECIO_U]
)

No luck

[Koichi_Tsuji]

COUNT([CMVINV_Inline][ID_INVITEMS])=COUNT([CMVINV_Inline][PRECIO_U]-LIST(""))

What about this ?

[SkrOYC]

Thanks!
This did the trick:

COUNT([CMVINV_Inline][ID_INVITEMS])=COUNT([CMVINV_Inline][PRECIO_U]-LIST(""))

Since I want it to return true if there is any column left, I needed to check if [CMVINV_Inline][PRECIO_U] minus the blank ones is the same as the count of the ID.
Your tip worked like charm!

PS: Can you change your expression from <> to = so that I can mark yours as the solution?

[Koichi_Tsuji]

Great to hear it was solved. Correction is made.

[SkrOYC]

I’m very sorry @tsuji_koichi but I jumped too soon!
It’s not working as expected. Neither <> or =
Now, credits to you because the expression that you wrote first with <> was right, it just didn’t work.

SkrOYC:

Since I want it to return true if there is any column left, I needed to check if [CMVINV_Inline][PRECIO_U] minus the blank ones is the same as the count of the ID.

^ My bad. If I substract the blank ones from the [PRICE_U] list, it’s COUNT() should be the same as the one for the keys. So if both COUNT() are the same, there is no blank values, and I need the opposite.
I’m sorry again and I’m still working on this

[bonameblisto]

Some hours ago Im have such problem with "blank"s.
Min() ddnt understand them.
But Im solved my trouble by incrementing all values by 1
Is that help you?

[SkrOYC]

Yeah, it’s a little bit problematic

[SkrOYC]

Update 2

• When [PRICE_U] has no values, COUNT([CMVINV_Inline][PRECIO_U]) counts the number of fields, eventhough they are blank
• When [PRICE_U] has no values, COUNT([CMVINV_Inline][PRECIO_U]-LIST("")) counts 0. That’s OK but it also counts just the unique values, just like if it where COUNT(UNIQUE([CMVINV_Inline][PRECIO_U]-LIST(""))). So if [CMVINV_Inline][PRECIO_U] is {1, 1, , 12} ; COUNT()=2

[Koichi_Tsuji]

COUNT(UNIQUE([CMVINV_Inline][PRECIO_U]-LIST("")))
COUNT([CMVINV_Inline][PRECIO_U]-LIST(""))`

Above two expression should be equivalent in theory.

[SkrOYC]

It’s working like that.
But I don’t need to count just the unique values, I need every field, it shouldn’t matter if one value is more than once in the list

[SkrOYC]

I’m under “Legacy” on Data → Options → Expression
I’m gonna check if “Consistent” helps

[Koichi_Tsuji]

Yes thats the point of the check.

[Koichi_Tsuji]

SkrOYC:

COUNT([CMVINV_Inline][ID_INVITEMS])=COUNT([CMVINV_Inline][PRECIO_U]-LIST(""))

Otherwise maybe it is an idea that you add the virtual column to refernced table, with expression
IF(ISNOTBLANK([PRECIO_U]),1,0), named it [CountCheck]

Then alter expression to

COUNT([CMVINV_Inline][ID_INVITEMS])=SUM([CountCheck])
COUNT([CMVINV_Inline][ID_INVITEMS])<>SUM([CountCheck])

either way to fit your requirement as alternative workaround?

[SkrOYC]

@tsuji_koichi
I though about that but it’ll be very messy with a lot of VC after a while
Right now I have 70 rows where each one of them has the [CMVINV_Inline] field with between 2 to 20~ rows.
So that would be 140 to 1400 AppFormulas

[Steve]

Try:

ISNOTBLANK(
  SELECT(
    [CMVINV_Inline][_ROWNUMBER],
    ISBLANK([PRECIO_U])
  )
)

[SkrOYC]

Interesting.
On the editor Test shows it working as I want it to work.
Y when there is at least one field blank, N when there aren’t.
On the App it seems like it’s always N

[SkrOYC]

Update 3

These didn’t work

ISNOTBLANK(
  FILTER(
    "DIM_INVITEMS",
    ISBLANK([PRECIO_U])
  )
)

---

IN(
  LIST(""),
  [CMVINV_Inline][PRECIO_U]
)

[SkrOYC · Accepted solution]

Woohoo!
This is the one

COUNT(
  INTERSECT(
    [CMVINV_Inline][PRECIO_U],
    LIST("")
  )
)<>0

As soon as I add a value inside the last row that was blank, the action dissapears. If I remove the content of any of the rows, leaving it blank, the action come back!

That was a lot of formulas to find the right way
Thanks @Steve and @tsuji_koichi for your valuable time!