List of email who can add and update the table

[Laup20]

Hi Good Day having trouble with the expression

I want to set a email who can add from this table the other emails can view or read only. I have also another table or directory where the emails are located (can add from that table)

Hope, you can help me with the expression. Thank you

[1minManager]

One way to do it…

IF(
OR(UserEmail()=“ABC.com”,UserEmail()=“XYZ.com”)
“ADDS_AND_UPDATES”,
“READ_ONLY”
)

[Steve]

If the email addresses of the users who can add rows are stored in another table named Privileged Users, try:

IF(
  IN(USEREMAIL(), Privileged Users[Email]),
  "ADDS_ONLY",
  "READ_ONLY"
)

If instead there is another table named Users where users that are allowed to add rows are indicated by a Yes/No-type column named May add rows? with a TRUE value:

IF(
  IN(
    USEREMAIL(),
    SELECT(
      Users[Email],
      [May add rows?]
    )
  ),
  "ADDS_ONLY",
  "READ_ONLY"
)

Or if you just want to identify the users explicitly:

IF(
  IN(
    USEREMAIL(),
    LIST(
      "user1@domain1",
      "user2@domain2",
      "user3@domain3"
    )
  ),
  "ADDS_ONLY",
  "READ_ONLY"
)

[Laup20]

Thank you @Steve and @1minManager for the help i already got the formula when i tried it first it was column not found but expression checker is marked as green. I tried so save several times then it was all good now. Thank you