Multiple "row selected" event actions?

Hi there,

Within this app, we have a “menu” that allows for users to select multiple options. I currently have a behavior set up for each row (orange buttons, right side). However, it would be a lot nicer if our users could select any given row and be automatically directed to their selected choice. As seen here, you can only have one row selected for an event action. Currently, if one selects any given row, they are directed to that row’s “Detailed” view - which only contains an image, name of the selected option, and the behavior action bubble (orange icon).

Is it possible to introduce multiple event actions?

Thanks,

@tbolhuis
It’s doable quite easily. Create an action for your menu table with Data: goto another view within this app and for the target assign an expression like this (it’s just to give an idea, may not reflect your schema):

IFS(
	[ID]="ID001",LINKTOVIEW("Settings"),
	[ID]="ID002",
	IFS(
		COUNT(SELECT(TransferLog[ID],AND([BUS ID]=USERSETTINGS("BusID"),DATE([CREATED])=TODAY())))=0,
		LINKTOFORM("TransferLog_Form 2","BUS ID",USERSETTINGS("BusID"),"DRIVER NAME",LOOKUP(USERSETTINGS("BusID"),"BusSchedule","BUS ID","DRIVER NAME"),"BUS MONITOR",LOOKUP(USERSETTINGS("BusID"),"BusSchedule","BUS ID","BUS MONITOR")),
		TRUE,LINKTOROW(ANY(SELECT(TransferLog[ID],AND([BUS ID]=USERSETTINGS("BusID"),DATE([CREATED])=TODAY()))),"TransferLog_Form 2")
	),
	[ID]="ID003",LINKTOFILTEREDVIEW("Students",[BUS ID]=USERSETTINGS("BusID")),
	[ID]="ID004",LINKTOFORM("ref_DropOffManifest_Form", "BUS ID",USERSETTINGS("BusID")),
	[ID]="ID005",LINKTOFORM("ref_PickUpManifest_Form", "BUS ID",USERSETTINGS("BusID")),
	[ID]="ID006",LINKTOFILTEREDVIEW("Students",[BUS ID]=USERSETTINGS("BusID")),
	[ID]="ID008",LINKTOVIEW("Trip Menu"),
	[ID]="ID009",LINKTOFILTEREDVIEW("FirstAidInventory_Inline",[BUS ID]=USERSETTINGS("BusID")),
	[ID]="ID010",LINKTOFILTEREDVIEW("BusEvacuationDrill_Inline",[BUS ID]=USERSETTINGS("BusID")),
	[ID]="ID011",LINKTOFILTEREDVIEW("Students",[BUS ID]=USERSETTINGS("BusID"))
)

After that assign this action to the Row Selected property of your Deck View of that menu.

3 Likes