Trying to set a security filter 'Orders Table' : where it only shows each users their orders

[Rurrea]

and(ANY(SELECT(AOD[Salesperson ID], ([Email] = useremail())))=[SalesPerson],[Order Date]>=today()-12)
Above formula works perfect and shows each user all their orders.

However i need it to show their Splitsale too:: So at the end of the day, if the users name pops up in either field as [salesperson] or [splitsale], then i need that user to have access to it.
[Salesperson], [Splitsale] : Both are fields in Orders Table that chooses reps name.

I wrote it several ways but doesnt seem to work. Any ideas

[Lynn]

Hi @Rurrea
Have you tried using OR() ?

help.appsheet.com

OR()

Are any true?

help.appsheet.com

Yes/No Expressions

Write expressions where the result is either TRUE or FALSE.

[Rurrea]

Tried the “or” option but it misreads it

[Steve]

No, you’re misusing it.

[Rurrea]

Or(and(ANY(SELECT(AOD[Salesperson ID], ([Email] = useremail())))=[SalesPerson], and(ANY(SELECT(AOD[Salesperson ID], ([Email] = useremail())))=[Splitsale]),[Order Date]>=today()-12)

Tried something like this but it misreads it and just ends up filtering all orders 12 days back for everyone

[Rurrea]

What I’m I doing wrong or what would u do? Would love to figure this out tonight

[Marc_Dillon]

Your logic is wrong, the general syntax should be

AND(
  date comparison ,
  OR(
    [salesperson] comparison ,
    [splitsale] comparison
  )
)

[Rurrea]

And([Order Date]>=today()-12,or(ANY(SELECT(AOD[Salesperson ID], ([Email] = useremail())))=[SalesPerson], ANY(SELECT(AOD[Salesperson ID], ([Email] = useremail())))=[splitsale]))

Solution still didn’t work. Unless I’m doing it wrong

[Steve · Accepted solution]

AND(
  ([Order Date] >= (TODAY() - 12)),
  ISNOTBLANK(
    INTERSECT(
      LIST(
        [Salesperson],
        [SplitSale]
      ),
      SELECT(
        AOD[Salesperson ID],
        (USEREMAIL() = [Email])
      )
    )
  )
)

[Rurrea]

Worked perfectly