Workflow Email is not working

I need to have an email sent when the value of a column reached below 3000.
condition expression test says it’s “TRUE” but I still haven’t got this working.

what I have been doing wrong?

my expression:
OR(Any(Select(Order Details[Dipstick Closing],AND([Product Name]= “Diesel”,[Timestamp]=Max(Order Details[Timestamp]))))<3000,
Any(Select(Order Details[Dipstick Closing],AND([Product Name]= “Premium”,[Timestamp]=Max(Order Details[Timestamp]))))<3000,
Any(Select(Order Details[Dipstick Closing],AND([Product Name]= “Unleaded”,[Timestamp]=Max(Order Details[Timestamp]))))<3000)

Workflows trigger when data is changed. Specifically, data in real columns in the table that the Workflow is set up on. That trigger is separate from the condition expression. I suspect that your problem is that the workflow itself is not being triggered.

2 Likes

HI Marc,
I have changed the Update event to ALL_CHANGES.

Works now.

thanks

2 Likes

Your expression, reformatted for clarity:

OR(
  ANY(
    SELECT(
      Order Details[Dipstick Closing],
      AND(
        ([Product Name] = "Diesel"),
        ([Timestamp] = MAX(Order Details[Timestamp]))
      )
    )
  )
  < 3000,
  ANY(
    SELECT(
      Order Details[Dipstick Closing],
      AND(
        ([Product Name] = "Premium"),
        ([Timestamp] = MAX(Order Details[Timestamp]))
      )
    )
  )
  < 3000,
  ANY(
    SELECT(
      Order Details[Dipstick Closing],
      AND(
        ([Product Name] = "Unleaded"),
        ([Timestamp] = MAX(Order Details[Timestamp]))
      )
    )
  )
  < 3000
)

Your expression, made more efficient:

ISNOTBLANK(
  FILTER(
    "Order Details",
    AND(
      ([Dipstick Closing] < 3000),
      IN([Product Name], LIST("Diesel", "Premium", "Unleaded")),
      ([Timestamp] = MAX(Order Details[Timestamp]))
    )
  )
)
1 Like