show column if before value is not empty

[Julio_Moyano]

Hi, 

I have tried to find a way to not display column if the before value is empty

I have a table like this:

Id	area	attachment pdf	datetime attachment
12	marketing	file_2	12-02-23 12:00
13	finance	file_3	13-02-23 12:00
14	finance	file_4	14-02-23 12:00
15	marketing
16	marketing

My desire is if marketing area not uploaded the file (attachment pdf) on id =15 they can not to upload the file in id = 16 (not show column attachment pdf) but finance can do it  because before is not empty (id = 14)

[datetime attachment] is a formula NOW() when upload the file

I have tried with [_THISROW_BEFORE] and ISNOTBLANK but is not working

thanks

[Steve]

Slice row filter conditions - AppSheet Help

[Julio_Moyano]

Thanks @Steve 

But if I create a slice filter then it does not  show me the whole row, I need to see the row and not show me the column when the value [datetime attachment]  from previous row is empty

[Steve · Accepted solution]

Oops! I didn't read your post closely. Sorry about that!

Try using this as the Edit? expression for the attachment.pdf column:

AND(
  ISNOTBLANK([area]),
  ISNOTBLANK(
    FILTER(
      "table",
      AND(
        ISBLANK([attachment.pdf]),
        ([_THISROW].[area] = [area]),
        ([_THISROW].[_ROWNUMBER] > [_ROWNUMBER])
      )
    )
  )
)

Which means: allow the upload only if an area is given (ISNOTBLANK([area]) and there are no prior rows ([_THISROW].[_ROWNUMBER] > [_ROWNUMBER]) with that same area ([_THISROW].[area] = [area]) with no attachment.pdf (ISBLANK([attachment.pdf])).

[Julio_Moyano]

Hi @Steve thank you, I really appreciate your help

I had to do a few changes

I changed ISNOTBLANK for ISBLANK in the line 3 and changed [ attachment pdf] for [datetime attachment] because appsheet not recognize that it is empty

AND(
  ISNOTBLANK([area]),
  ISBLANK(
    FILTER(
      "table",
      AND(
        ISBLANK([datetime attachment]),
        ([_THISROW].[area] = [area]),
        ([_THISROW].[_ROWNUMBER] > [_ROWNUMBER])
      )
    )
  )
)

[Steve]

Well done!